feat: Use explicit linker script for 1MB flash B/W radios (#4244)

radio/src/targets/taranis/CMakeLists.txt

@@ -231,7 +231,7 @@ elseif(PCB STREQUAL X7)
     set(MODULE_SIZE_STD YES)
     set(FLAVOUR boxer)
     set(NAVIGATION_TYPE x7)
-    set(CPU_TYPE_FULL STM32F407xE)
+    set(CPU_TYPE_FULL STM32F407xG)
     set(ROTARY_ENCODER YES)
     set(USB_CHARGER YES)
     add_definitions(-DRADIO_BOXER)
@@ -449,7 +449,12 @@ elseif (CPU_TYPE_FULL STREQUAL STM32F407xE)
   set(CPU_TYPE STM32F4)
   add_definitions(-DSTM32F407xx)
   add_definitions(-DSTM32F40_41xxx -DSTM32F407xx)
-  set(LINKER_SCRIPT targets/taranis/stm32f4_flash.ld)
+  set(LINKER_SCRIPT targets/taranis/stm32f4_512k_flash.ld)
+elseif (CPU_TYPE_FULL STREQUAL STM32F407xG)
+  set(CPU_TYPE STM32F4)
+  add_definitions(-DSTM32F407xx)
+  add_definitions(-DSTM32F40_41xxx -DSTM32F407xx)
+  set(LINKER_SCRIPT targets/taranis/stm32f4_1m_flash.ld)
 elseif (CPU_TYPE_FULL STREQUAL STM32F413xG)
   set(CPU_TYPE STM32F4)
   add_definitions(-DSTM32F413xx)

radio/src/targets/taranis/stm32f4_1m_flash.ld

@@ -0,0 +1,180 @@
+/*
+*****************************************************************************
+**
+**  File        : stm32f4_1m_flash.ld
+**
+**  Abstract    : Linker script for STM32F407 Device with
+**                1MByte FLASH, 128KByte SRAM, 64KByte CCM
+**
+**                Set heap size, stack size and stack location according
+**                to application requirements.
+**
+**                Set memory bank area and size if external memory is used.
+**
+**  Target      : STMicroelectronics STM32
+**
+*****************************************************************************
+*/
+
+/* Entry Point */
+ENTRY(Reset_Handler)
+
+/* Highest address of the user mode stack */
+_estack = 0x10010000;    /* end of 64K CCM */
+_heap_end = 0x20020000;  /* end of 128K SRAM */
+
+/* Generate a link error if heap and stack don't fit into RAM */
+_Min_Heap_Size = 0;      /* required amount of heap  */
+_Main_Stack_Size = 1024; /* required amount of stack for interrupt stack (Main stack) */
+
+/* Main stack end */
+_main_stack_start = _estack - _Main_Stack_Size;
+
+/* Specify the memory areas */
+MEMORY
+{
+  FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 1024K
+  RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 128K
+  CCM (xrw)       : ORIGIN = 0x10000000, LENGTH = 64K
+  MEMORY_B1 (rx)  : ORIGIN = 0x60000000, LENGTH = 0K
+}
+
+/* Define output sections */
+SECTIONS
+{
+  /* The startup code goes first into FLASH */
+
+  /* The program code and other data goes into FLASH */
+  .text :
+  {
+    FILL(0xFFFF)
+      
+    CREATE_OBJECT_SYMBOLS
+
+    KEEP(*(.bootloader)) /* Bootloader code */
+      
+    . = 0x8000;          /* Set the start of the main program */
+    _stext = .;          /* Provide the name for the start of this section */
+    . = ALIGN(4);
+    KEEP(*(.isr_vector)) /* Startup code */
+    KEEP(*(.fwversiondata))
+    *(.text)           /* .text sections (code) */
+    *(.text*)          /* .text* sections (code) */
+    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
+    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
+    *(.glue_7)         /* glue arm to thumb code */
+    *(.glue_7t)        /* glue thumb to arm code */
+    *(.eh_frame)
+    *(.data.__global_locale)
+
+    KEEP (*(.init))
+    KEEP (*(.fini))
+
+    . = ALIGN(4);
+    _etext = .;        /* define a global symbols at end of code */
+  } >FLASH
+
+
+   .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
+    .ARM : {
+    __exidx_start = .;
+      *(.ARM.exidx*)
+      __exidx_end = .;
+    } >FLASH
+
+  .preinit_array     :
+  {
+    PROVIDE_HIDDEN (__preinit_array_start = .);
+    KEEP (*(.preinit_array*))
+    PROVIDE_HIDDEN (__preinit_array_end = .);
+  } >FLASH
+  .init_array :
+  {
+    PROVIDE_HIDDEN (__init_array_start = .);
+    KEEP (*(SORT(.init_array.*)))
+    KEEP (*(.init_array*))
+    PROVIDE_HIDDEN (__init_array_end = .);
+  } >FLASH
+  .fini_array :
+  {
+    PROVIDE_HIDDEN (__fini_array_start = .);
+    KEEP (*(.fini_array*))
+    KEEP (*(SORT(.fini_array.*)))
+    PROVIDE_HIDDEN (__fini_array_end = .);
+  } >FLASH
+
+  /* used by the startup to initialize data */
+  _sidata = .;
+
+  /* Initialized data sections goes into RAM, load LMA copy after code */
+  .data :
+  {
+    . = ALIGN(4);
+    _sdata = .;        /* create a global symbol at data start */
+    *(.data)           /* .data sections */
+    *(.data*)          /* .data* sections */
+
+    . = ALIGN(4);
+    _edata = .;        /* define a global symbol at data end */
+  } >CCM AT> FLASH
+
+  /* Uninitialized data section */
+  . = ALIGN(4);
+  .bss :
+  {
+    /* This is used by the startup in order to initialize the .bss secion */
+    _sbss = .;         /* define a global symbol at bss start */
+    /* __bss_start__ = _sbss; */
+    *(.bss)
+    *(.bss*)
+    *(COMMON)
+
+    . = ALIGN(4);
+    _ebss = .;         /* define a global symbol at bss end */
+    /* __bss_end__ = _ebss; */
+  } >CCM
+
+  /* collect all uninitialized .ccm sections */
+  .ram (NOLOAD) :
+  {
+    . = ALIGN(4);
+    _sram = .;
+    /* __ccm_start__ = _sccm; */
+    *(.ram)
+    . = ALIGN(4);
+    _eram = .;
+    /* __ccm_end__ = _eccm; */
+  } >RAM
+  
+  PROVIDE ( end = _eram );
+  PROVIDE ( _end = _eram );
+
+  /* User_heap_stack section, used to check that there is enough RAM left */
+  ._user_heap_stack :
+  {
+    . = ALIGN(4);
+    . = . + _Min_Heap_Size;
+    . = . + _Main_Stack_Size;
+    . = ALIGN(4);
+  } >RAM
+
+  /* MEMORY_bank1 section, code must be located here explicitly            */
+  /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
+  .memory_b1_text :
+  {
+    *(.mb1text)        /* .mb1text sections (code) */
+    *(.mb1text*)       /* .mb1text* sections (code)  */
+    *(.mb1rodata)      /* read-only data (constants) */
+    *(.mb1rodata*)
+  } >MEMORY_B1
+  
+  /* Remove information from the standard libraries */
+  /DISCARD/ :
+  {
+    libc.a ( * )
+    libm.a ( * )
+    libgcc.a ( * )
+  }
+
+  .ARM.attributes 0 : { *(.ARM.attributes) }
+}

radio/src/targets/taranis/stm32f4_512k_flash.ld

@@ -1,7 +1,7 @@
 /*
 *****************************************************************************
 **
-**  File        : stm32f4_flash.ld
+**  File        : stm32f4_512k_flash.ld
 **
 **  Abstract    : Linker script for STM32F407 Device with
 **                0.5MByte FLASH, 128KByte SRAM, 64KByte CCM